예맥성 스크립트

Script    자둔엔피씨    {
    set @id, myid();
    set @sd, mysd();
    callfunc("승급제한", 4);
A:
    switch($jadoon)
    {
    case 0:
        set @m, list1("어서오시오. 이곳은 어떻게 오셨소?","새로운 곳을 탐험하고 싶어 왔습니다.","그냥 지나가는 길입니다.");
        if(@m != 1) { end; }

        set @pv, list2(@s,0,0,"정말 여유로운 모험가신것같소. 예맥성은 예로부터 평화롭기로 유명한 민족의 마을이오. 하지만 언제 부터인가 몬스터들이 들끓기 시작했소.. 주변에 몬스터들은 보셨소?","네, 정말 무시무시 하더군요.","하나도 안보이던데요?");
        switch(@s)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,0,"저런.. 거짓을 말하다니 모험가라는 것이 순 거짓말쟁이들만 모인것이오? 당신은 예맥성에 들어 갈 수 없소. 되돌아가시오!");
            end;
        }

        set @pv, dialog(0,0,1,"그렇소.. 언제 부터 인지는 모르겠으나, 요근래 부쩍 몬스터들이 예맥성을 떠도는것이.. 무척이나 수상해 우리 예맥족들은 그들이 어떻게 이곳에 나타나게 되었는지."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"그리고 그들이 추종하는 추종자가 누구인지.. 알아 낼 수 있다면, 무엇을 못하겠소??"); if(@pv == 0) { end; }

        set @pv, list2(@j,0,0,"만약 모험가인 그대가, 저 몬스터들을 저지하고, 그들의 추종자를 누군지 알아 내 준다면 예맥성안으로 들여보내드리겠소. 나의 제안이 어떻소?","그 제안 받아드리지요.","너무 무섭네요.. 다음에 다시 올게요.");
        switch(@j)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,0,"...내 다른사람을 찾아 보리다.. 어서 당신의 마을로 물러가시구려. 이곳에는 당신같은 사람이 올 곳이 아니오.");
            end;
        }

        set @pv, dialog(0,0,1,"나의 제안을 받아 들여 주어서 정말 고맙소."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"우선 이 주변을 어슬렁 거리는 몬스터인 망연괴 8마리와 수촉벌레 8마리를 잡아 와주시오. 그렇다면 당신을 예맥성의 입구로 보내드리겠소."); if(@pv == 0) { end; }
        set $jadoon, 1;
        end;
    case 1:
        if($m558 < 8 || $m559 < 8)
        {
            set @pv, list2(@m,0,0,"이 주변을 어슬렁 거리는 몬스터 망연괴와 수촉벌레를 8마리씩 처치하고 되돌아 와주시오.","망연괴: "+$m558+" / 8마리","수촉벌레: "+$m559+" / 8마리");
            end;
        }

        set @pv, list2(@s,0,0,"내가 부탁한 망연괴와 수촉벌레를 모두 처치하고 돌아오셨소?","네, 모두 처치했습니다.","아니요 아직..");
        switch(@s)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,0,"다시 돌아가 모두 처치하고 되 돌아 오시오.. 근데 내가 보기에는 이미 충분히 처치한걸로 보이는데..");
            end;
        }

        set $jadoon, 2;
        goto A;
    case 2:
        set @pv, dialog(0,0,0,"정말 고맙소. 모험가인 그대 덕분에 이곳 몬스터의 개체수가 많이 줄은것같소.. 문을 열어놓았으니 어서 예맥성으로 가보시오. 그곳은 지금 어떤 상황인지.. 상상도 안가는군..");
        end;
    }
}
Script    나약한보초엔피씨    {
    set @id, myid();
    set @sd, mysd();
    callfunc("소지품공간", 1);
A:
    switch($ymsboco)
    {
    case 0:
        set @m, list1("아.. 정말 큰일이군 큰일이야..","무슨 일이시죠?");
        if(@m != 1) { end; }

        set @pv, dialog(0,0,1,"자네는 부여에서 온 모험가인가? 그렇다면 정말 다행일세. 부여인인즉 탁월한 힘을 지니고 있는 자들인데.."); if(@pv == 0) { end; }
        set @pv, list2(@s,0,0,"조금 힘들 수 있지만, 나의 부탁을 들어 줄 수 있겠나?","무슨 부탁인지는 모르지만 일단 들어보죠.","제가 갈 길이 바빠서..");
        switch(@s)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,0,"이런.. 정말 안됫군.. 알겠네 가던 길 가게나.");
            end;
        }

        set @pv, dialog(0,0,1,"이야기라도 들어 준다니, 정말 고맙네. 자네도 보았듯이 예맥성 근처마다 몬스터들이 계속 출몰하고 있네.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"그래서 그런지, 이곳 예맥성의 입구까지 몬스터가 출몰 했는데.. 예맥성에 바쳐야할 <볏짚>들을 <황지네>들에게 빼앗겨 버렸네.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"빼앗겼다는 것보다는 그 몬스터들이 먹어치웟다고 보는것이 옳겠군."); if(@pv == 0) { end; }

        set @pv, list2(@s,0,0,"혹시, 예맥성에 가는 길이라면 부디 나의 부탁을 들어주게. 내 그럼 자네가 예맥성에 갈 수 있도록 문을 열어주겠네.","그런 부탁 쯤이야 들어드리죠!","죄송합니다. 너무 무섭네요..");
        switch(@s)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,0,"하긴.. 나도 무서운데 자네는 안무섭겠나? 알겠네. 돌아가보게나..");
            end;
        }

        set $ymsboco, 1;

        set @pv, dialog(0,0,1,"정말 고맙네 고마워! 황지네들은 단단한 입으로 사람들을 공격하고 또 위협하는 무서운 존재네.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"몸집은 작지만 그 빠른 몸놀림이 사람들을 위협하기에는 충분하지.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"황지네를 처치하고, 내게 <예맥성볏짚 3개>만 가져다주게. 예맥성 장로님에게 드려야 하는데 이건뭐.. 어찌저찌 하지도 못하고.."); if(@pv == 0) { end; }

        end;
    case 1:
        if(pc_amountitem(@sd, name2itemid("예맥성볏짚")) < 3)
        {
            set @pv, dialog(0,0,1,"예맥성볏짚 3개는 이 주위에 출몰해있는 <황지네>라는 놈들에게 얻을 수 있을걸세.. 그놈들이 다 먹어 치워버렸으니.. 이걸 어쩌겠나..");
            end;
        }

        set @s, list1("그래, 예맥성볏짚 3개는 다 모아왔나?","네, 여기 있습니다.","아니요 조금만 더 기다려주세요.");
        if(@s != 1) { end; }

        if(pc_amountitem(@sd, name2itemid("예맥성볏짚")) < 3) { end; }

        delitem @sd, name2itemid("예맥성볏짚"), 3;
        message @sd, 3, "예맥성볏짚 3개 주었습니다.";

        set $ymsboco, 2;

        set @pv, dialog(0,0,1,"오.. 정말 예맥성의 볏짚이 맞군! 정말 고맙네. 이제 한시름 놓아도 되겠구만.. 음?");
        goto A;
    case 2:
        if(pc_amountitem(@sd, name2itemid("물고기비늘")) < 2)
        {
            switch($ymsboco2)
            {
            case 0:
                set @s, list1("아차! 깜빡 잊어 버린것이 있네. 미안하지만 내 부탁을 한가지만 더 들어 줄 수 있겠나?","그 부탁 그냥 들어 드릴게요.","아니요. 정말 바빠서..");
                switch(@s)
                {
                case 0:
                    end;
                case 2:
                    set @pv, dialog(0,0,1,"그럼 할 수 없겠군.. 자네의 마을로 돌아가는 수밖에는 없네.. 나도 꽁짜로는 보내 줄 수는 없지.");
                    end;
                }

                set $ymsboco2, 1;
                goto A;
            case 1:
                set @pv, dialog(0,0,1,"이 입구 위쪽에 보면, 숨겨져 있는 동굴이 하나있는데.. 그곳에 걸어다니는 괴물 물고기들이 살고 있네."); if(@pv == 0) { end; }
                set @pv, dialog(0,0,1,"그 물고기들의 비늘은 신기하게도 황지네들이 이곳에 얼씬 못하도록 하는 효과를 가지고 있지..."); if(@pv == 0) { end; }
                set @pv, dialog(0,0,1,"물고기비늘을 2개만 가져다 주게. 꼭 좀 부탁하겠네!"); if(@pv == 0) { end; }
                end;
            }
        }

        set @s, list1("물고기들의 비늘 2개를 가지고 있다면, 내게 줄 수 있겠나?","네, 여기 드리겠습니다.","조금만 생각을 해볼게요.");
        switch(@s)
        {
        case 0:
            end;
        case 2:
            set @pv, dialog(0,0,1,"생각이 바뀐다면 나를 다시 찾아오게나. 그 비늘이 꼭 필요해서 말이야.."); if(@pv == 0) { end; }
            end;
        }

        if(pc_amountitem(@sd, name2itemid("물고기비늘")) < 2) { end; }

        set $ymsboco, 3;
        addlegend @sd, 22, 7, 16, "[악의추종자] 예맥족의 촌장 능선을 만나라.";

        delitem @sd, name2itemid("물고기비늘"), 2;
        message @sd, 3, "물고기비늘 2개 주었습니다.";

        additem @sd, name2itemid("짚신"), 1;

        set @pv, dialog(0,0,1,"정말 고생이 많았네. 이 <짚신>은 내가 자네에게 주는 선물일세. 예맥성의 장인들은 손재주가 참 좋아서 말이야!");
        set @pv, dialog(0,0,1,"이제 예맥성으로 갈 수 있을걸세.. 예맥성의 촌장님에게 자네가 간다는것을 미리 일러두었으니,");
        set @pv, dialog(0,0,1,"<예맥성촌장>님을 꼭 뵈도록 하게나. 그럼 이만..");
        end;
    case 3:
        set @pv, dialog(0,0,1,"예맥성에는 참 기이한 일들이 많이 일어나고 있지.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,0,"만약 <예맥성촌장>님을 한번도 안뵈었다면, 꼭 그분을 뵙도록하게나. 자네의 예맥성 모험에 도움을 주실 분이니..");
        end;
    }
}
Script    춘자엔피씨    {
    set @id, myid();
    set @sd, mysd();
a:
    set @pv, list2(@m,0,0,"어서오세요. 어떻게 오셨나요?","물건 사기","물건 팔기","금전 맡기기","금전 찾기","물건 맡기기","물건 찾기");
    switch(@m)
    {
    case 1:
        set @pv, list2(@m,0,1,"어떤 물품을 구매하실 껀가요?","비서","반지","주류");
        if(@pv == 0) { end; } else if(@pv == -1) { goto a; }
        switch(@m)
        {
        case 1:
            call_shop 0,1;
        case 2:
            call_shop 0,2;
        case 3:
            call_shop 0,20;
        default:
            end;
        }
    case 2:
        call_shop 1,19;
    case 3:
        call_deposit 0;
    case 4:
        call_withdraw 0;
    case 5:
        call_deposit 1;
    case 6:
        call_withdraw 1;
    }
}
Script    춘자말하기    {
    set @id, objid();

    set @r, rand(1,60);
    if(@r == 1) { say @id, 0, "춘자: 오라버니들! 여기서 푹~ 쉬고 모험나가세요~"; }
    else if(@r == 2) { say @id, 0, "춘자: 요즘 예맥성 주위에 무서운 몬스터들이 출몰 한다던데.."; }
    else if(@r == 3) { say @id, 0, "춘자: 동동주 한잔 어때요?"; }
    else if(@r == 4) { say @id, 0, "춘자: 예맥성의 모든 일은 북쪽의 예맥족 촌장 능선님을 만나보세요."; }
}
Script    능선엔피씨    {
    set @id, myid();
    set @sd, mysd();
A:
    set @pv, list2(@m,0,0,"할.할.할.. 어서오시게나. 예맥족의 촌장 능선이라 하는 노인일세. 나를 어떤 일로 찾아왔나?","예맥성에 대해 궁금합니다.","[4차] 악의추종자","[5차] 갈곳없는처녀귀신");
    switch(@m)
    {
    case 1:
        set @pv, dialog(0,0,1,"외지에서 왔으니.. 이 예맥성과 예맥족에 대해서는 당연히 알리가 있겠나? 내 차근히 알려 주도록 하겠네. 험험.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"이 곳은 중국의 땅에 속해있지만, 꼭 그렇지 만도 않은 성일세.. 대방성 근교에 자리잡고 있는 이 예맥성에는 다른 성과는 달리"); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"왕이나 그에 속한 규칙에 전혀 속해있지 않은 아주 자유로운 마을이지.. 하지만 기본적인 법에 대해서는 마을 사람들도 따라준다네."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"자네도 이곳에 오면서, 여러 종류의 몬스터들과 대면을 해보았을것이야.. 그들은 본래 이 마을에 있던 몬스터들이 아니지.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"그 흉악한 몬스터들은, 마을 사람들의 곡식이나 음식을 먹어 치우고 그리고 사람들까지 위협하는 아주 무서운 존재들이야.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"어디서 그 몬스터들이 나타낫는지, 그리고 대체 그 몬스터들이 추종하고 있는 추종자는 누구인지.. 알아 내서 더이상 이 예맥성을"); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"위협하는 무리들을 없애고, 다시 평화로운 마을로 만들기 위해, 우리들은 세계 곳곳의 수많은 모험가들을 찾고 있네.."); if(@pv == 0) { end; }
        goto A;
    case 2:
        callfunc("승급제한", 4);
B:
        switch($yaj)
        {
        case 0:
            set @pv, list2(@s,0,0,"할.할.할.. 정말 반갑구려. 입구의 보초에게 부여인인 그대가 온다는 말은 들었네.. 갑자기 나타난 몬스터에 대해 알아봐 준다고 했나?","예. 그렇습니다.","뭔가 잘못 들으신것 같네요.");
            switch(@s)
            {
            case 0:
                end;
            case 2:
                set @pv, dialog(0,0,0,"나이가 먹어 귀가 않좋아 진것같네.. 괜히 붙잡아 미안하구먼.. 할.할.할...");
                end;
            }

            set @pv, dialog(0,0,1,"그렇게 해준다니 정말 고마울 뿐일세. 할.할.할..  자네가 예맥을 위해 도와준 만큼, 우리들도 보상을 하도록 하겠네."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"아직 우리들은 출몰하는 몬스터들의 뒤에 아주 두려운 무언가가 있다고 가정만 할뿐, 정확히 아는 바는 없네만.."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"안그래도 이번에 아주 수상한 곳을 발견한 자가 있다네. 그는 황엽이라고 하는 예맥성의 주민이지.."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"자신의 집 지하에 창고를 만들려다가, 무언가를 발견 했다고는 하는데.. 그 곳에서 아주 기이한 소리가 난다고 하더군.."); if(@pv == 0) { end; }
            set @pv, list2(@s,0,0,"한번 자네가 황엽에게 가서 조사를 해 줄 수 있겠는가?","네, 그럼 바로 조사를 시작하겠습니다.","조금 더 시간을 주세요..");
            switch(@s)
            {
            case 0:
                end;
            case 2:
                set @pv, dialog(0,0,0,"우리 예맥족의 미래가 달려 있는 일 일세.. 꼭좀 도와주길 부탁하네.");
                end;
            }

            set $yaj, 1;
            addlegend @sd, 22, 7, 16, "[악의추종자] 황엽을 만나라.";
            set @pv, dialog(0,0,1,"음.. 알겠네. 할.할.할.. 황엽의 집은 여기서 오른쪽으로 조금만 가면 보일것이네.. 한번 황엽을 만나보도록 하게나."); if(@pv == 0) { end; }
            end;
        case 1:
            set @pv, dialog(0,0,1,"황엽의 집은 이곳에서 오른쪽으로 조금만 가면 보일것이네.. 한번 그에게 무슨일이 있었나 물어보도록 하게나. 할.할.할..");
            end;
        case 2:
            set @pv, dialog(0,0,1,"황엽의 집은 이곳에서 오른쪽으로 조금만 가면 보일것이네.. 한번 그에게 무슨일이 있었나 물어보도록 하게나. 할.할.할..");
            end;
        case 3:
            set @s, list1("그래, 황엽의 집에서의 모든 조사는 다 끝냇는가?","네, 모두 조사했습니다.","아니요 아직..");
            if(@s != 1) { end; }
            set $yaj, 4;
            goto B;
        case 4:
            set @pv, dialog(0,0,1,"음.. 그렇게 된거였군. 정말 고맙네. 자네덕분에 연합군에게 도움을 청할 일만 남았네."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,0,"만약 자네도 연합군에 속해 있다면, 연합군의 지시를 받게나 할.할.할.."); if(@pv == 0) { end; }
            end;
        }
    case 3:
        callfunc("승급제한", 5);
        set @pv, dialog(0,0,1,"요 근래 예맥흉가에 어떤 못된놈이 들어서버렸다고 하는군.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"그래서 원래 있던 힘없는 귀신들이 다 밖으로 내쫓아져 버렸지..."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,0,"예맥성 서쪽에 낡고 허름한 집이 있는데, 거기가서 처녀귀신을 만나 도와주게나."); if(@pv == 0) { end; }
        end;
    }
}
Script    능선말하기    {
    set @id, objid();

    if(rand(1,3) == 1) { action @id, rand(2,3), 30, 0; }

    set @r, rand(1,60);
    if(@r == 1) { say @id, 0, "능선: 어서오시구려.. 할.할.할.. 예맥족의 촌장 능선이라 하오리다.."; }
    else if(@r == 2) { say @id, 0, "능선: 갑자기 나타난 몬스터들이 마을의 아이들까지 위협하다니.. 이를 어쩌나.."; }
    else if(@r == 3) { say @id, 0, "능선: 이미 수많은 사람들이 몬스터들에게 피해를 입었소."; }
    else if(@r == 4) { say @id, 0, "능선: 부디 모험가 그대들의 주변인들에게 부탁해, 예맥을 도와주시오."; }
}
Script    황엽엔피씨    {
    set @id, myid();
    set @sd, mysd();
    set @pv, list2(@m,0,0,"어서오세요. 어떻게 오셨나요?","[4차] 악의추종자");
    switch(@m)
    {
    case 1:
        callfunc("승급제한", 4);
A:
        switch($yaj)
        {
        case 0:
            set @pv, dialog(0,0,0,"예맥성 북쪽 부근에 있는 능선 촌장님을 먼저 만나십시요.");
            end;
        case 1:
            set @m, list1("어서오십시요. 기다리고 있었습니다. 능선님이 말씀하신 그 분이 맞는지요?","예. 맞습니다.","다른 사람을 착각 하신것 같네요.");
            switch(@m)
            {
            case 0:
                end;
            case 2:
                set @pv, dialog(0,0,0,"저런.. 죄송합니다. 능선 촌장님께서 분명 어떤 모험가 한분을 소개시켜 준다고 하셨었거든요.. 죄송합니다.");
                end;
            }

            set @pv, dialog(0,0,1,"이런 누추한 곳 까지 와주셔서 정말 감사합니다."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"그럼 바로 말씀을 드려야겠네요.. 얼마전 저희집 지하에 창고를 만들려고 자리를 만드는 도중에"); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"지하 깊숙한 곳에서 어떤 기이한 소리를 들었습니다. 그래서 지하를 조금더 파보니, 어떤 넓은 지하를 발견했지요."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"순간 무언가가 제앞에 오는것같아 재빨리 몸을 피했습니다.. 너무 무서워서 촌장님에게 말씀드렸는데 이렇게도 당신께서 도와주시러"); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"오셨으니, 한시름이 놓아지는군요."); if(@pv == 0) { end; }

            set @pv, list2(@m,0,0,"그런데 중요한건 제가 지하창고에 보관하고 있던 아주 소중한 목걸이가 없어졌습니다.. 정말 중요한것인데 도와 주실 수 있겠나요?","그럴려고 여기 왔습니다. 얼마든지요!","조금 생각을 해 봐야 겠네요.");
            switch(@m)
            {
            case 0:
                end;
            case 2:
                set @pv, dialog(0,0,0,"준비가 되신다면 저를 찾아주세요. 아주 중요한 목걸이 인지라..");
                end;
            }

            set $yaj, 2;
            addlegend @sd, 22, 7, 16, "[악의추종자] 황엽의 지하창고를 조사하시오.";
            set @pv, dialog(0,0,0,"정말 고맙습니다. 지하창고는 여기 위에 보이는 계단을 타고 내려가시면 됩니다.. 부디 몬스터 조사와 함께 목걸이를 꼭 찾아주세요.");
            end;
        case 2:
            if(pc_amountitem(@sd, name2itemid("송유의목걸이")) < 1)
            {
                set @pv, dialog(0,0,0,"지하창고는 여기 위에 보이는 계단을 타고 내려가시면 됩니다.. 부디 몬스터 조사와 함께 목걸이를 꼭 찾아주세요.");
                end;
            }
            set @m, list1("혹시 조사를 하시다가 제 목걸이는 발견이 되었나요..?","네, 여기 가지고 왔습니다.","조금 더 찾아볼게요..");
            switch(@m)
            {
            case 0:
                end;
            case 2:
                set @pv, dialog(0,0,0,"예.. 꼭 부탁드립니다.");
                end;
            }
            if(pc_amountitem(@sd, name2itemid("송유의목걸이")) < 1) { end; }

            addlegend @sd, 22, 7, 16, "[악의추종자] 능선 촌장에게 조사내용 보고하라.";
            set $yaj, 3;

            delitem @sd, name2itemid("송유의목걸이"), 1;
            additem @sd, name2itemid("연합군패"), 4;
            set_money @sd, get_money(@sd) + 80000;
            set_birth @sd, get_birth(@sd) + 400;

            set @pv, dialog(0,0,1,"정말 감사합니다.. 제 목걸이를 찾아주시다니 이걸 어떻게 보상을 해드려야 할지.."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"이건 제 마음입니다. 꼭 받아주세요!\n\n보상(1): 연합군패 4개\n보상(2): 은전 80,000전\n보상(3): 주화 400원"); if(@pv == 0) { end; }
            goto A;
        case 3:
            set @pv, dialog(0,0,0,"이제, 능선 촌장님에게 저희집 지하 조사에 대해서 보고하세요. 정말 중요한 정보가 될것입니다.");
            end;
        case 4:
            set @pv, dialog(0,0,0,"이제, 능선 촌장님에게 저희집 지하 조사에 대해서 보고하세요. 정말 중요한 정보가 될것입니다.");
            end;
        }
    }
}
Script    당쇠엔피씨    {
    set @id, myid();
    set @sd, mysd();
a:
    set @m, list1("어서오세요. 어떻게 오셨나요?","물건사기","물건팔기","물건 고치기","모두 고치기","무기 별칭 명명","무기를 강화하고 싶어요");
    switch(@m)
    {
    case 1:
        set @pv, list2(@m,0,1,"어떤 물건을 사실건가요?\n\n장비를 강화하시려면, 강화부적을\n구매 해주세요.\n또는 장비를 구매해보세요.","1, 장비 및 기타","2. 장비강화부적( 인기! )");
        if(@pv == 0) { end; } else if(@pv == -1) { goto a; }
        switch(@m)
        {
        case 1:
            call_shop 0,38;
        case 2:
            call_shop 0,22;
        default:
            end;
        }
    case 2:
        call_shop 1,29;
    case 3:
        call_repair;
    case 4:
        call_allrepair;
    case 5:
        call_naming;
    case 6:
        dialog 1,0,0,"정말 좋은 질문이야. 무기 뿐만이 아니라, 투구,갑옷,반지,보조,방패까지 다양하게 강화가 가능하다는걸 잊지말도록 하게. 강화는 부여성의 주막에 있는 강화장인이나, 나에게 비서를 사서 하면되네.";
        goto a;
    default:
        end;
    }
}
Script    푸주선엔피씨    {
    set @id, myid();
    set @sd, mysd();
a:
    set @pv, list2(@m,0,0,"안녕하세요. 어떻게 오셨나요?","물건 사기","물건 팔기","말린지네 만들기","가죽종이 만들기","금강조각 만들기","비료포대 만들기");
    if(magic_aethered(@sd, 506) == 1)
    {
        message @sd, 3, "제작도중 또다른 아이템을 제작할수 없습니다.";
        end;
    }
    switch(@m)
    {
    case 1:
        call_shop 0,18;
    case 2:
        call_shop 1,31;
    case 3:
        if(pc_amountitem(@sd, 373) < 7)
        {
            dialog 0,0,0,"말린지네를 만드시려면, 죽은지네가 7개 필요하답니다.";
            end;
        }
        delitem @sd, 373, 7;
        additem @sd, 374, 1;
        dialog 0,0,0,"말린지네 여기 있습니다. 아주 잘 말려졌는데요?";
        end;
    case 4:
        if(pc_amountitem(@sd, 778) < 10)
        {
            dialog 0,0,0,"가죽종이를 만드시려면, 사슴가죽 10개 필요하답니다.";
            end;
        }
        delitem @sd, 778, 10;
        additem @sd, 779, 1;
        dialog 0,0,0,"가죽종이 여기 있습니다. 아주 이쁜 종이네요?";
        end;
    case 5:
        if(pc_amountitem(@sd, 1105) < 8 || pc_amountitem(@sd, 255) < 1)
        {
            dialog 0,0,0,"금강조각을 만드려면, 수정동굴에서 나오는 금강가루 8개와 여기 밑 인형굴에서 구할수있는 백화검이 필요합니다.";
            end;
        }
        delitem @sd, 1105, 8;
        delitem @sd, 255, 1;
        effect @id, 272;sound @id, 0, 119; magic_aether @sd, 506, 11; sleep 11000;
        set @r, rand(1,2);
        if(@r != 1)
        {
            dialog 0,0,0,"백화검의 너무쌘 불길로, 금강가루들이 다 녹아버렸네요.";
            end;
        }
        additem @sd, 1106, 1;
        dialog 0,0,0,"금강조각 여기 있습니다. 이 조각이 행운을 불러다 준다는데.. 정말일까요?";
        end;
    case 6:
        if(pc_amountitem(@sd, 1360) < 10 || pc_amountitem(@sd, 1361) < 5)
        {
            dialog 0,0,0,"비료포대를 만드려면, 진흙덩어리 10개와 뱀의분비물 5개가 필요합니다.";
            end;
        }
        delitem @sd, 1360, 10;
        delitem @sd, 1361, 5;
        effect @id, 272;sound @id, 0, 119; magic_aether @sd, 506, 11; sleep 11000;
        set @r, rand(1,3);
        if(@r != 1)
        {
            dialog 0,0,0,"이 진흙과 뱀의분비물은 비료로 쓰이기에는 좀 안좋은 것들이네요. 다시 구해오셔야 할것 같습니다.";
            end;
        }
        additem @sd, 1362, 1;
        dialog 0,0,0,"비료포대 여기 있습니다. 아주 질이 좋은 비료라, 어떤 식물이든 빨리 키워줄것같네요.";
        end;
    default:
        end;
    }
}
Script    예맥성의깃발엔피씨    {
    set @id, myid();
    set @sd, mysd();
A:
    set @m, list1("사냥터로 이동 시켜 드립니다. 자신과 맞는 승급 사냥터를 선택 해 주세요.","[선택1] 4차 승급자 사냥터","[선택2] 5차 승급자 사냥터");
    switch(@m)
    {
    case 0:
        end;
    case 1:
        callfunc("승급제한", 4);
        set @pv, list2(@s,0,1,"사냥터 선택시 사냥터 안으로 자동이동 됩니다. 어떤 사냥터로 이동 하실건가요?","예맥고대발굴지");
        if(@pv == 0) { end; } else if(@pv == -1) { goto A; }

        if(@s == 1) { set @map, 2940; set @x, 6; set @y, 5; }
        else { end; }

        break;
    case 2:
        callfunc("승급제한", 5);
        set @pv, list2(@s,0,1,"사냥터 선택시 사냥터 안으로 자동이동 됩니다. 어떤 사냥터로 이동 하실건가요?","지하보급창고","예맥흉가");
        if(@pv == 0) { end; } else if(@pv == -1) { goto A; }

        if(@s == 1) { set @map, 2935; set @x, rand(1,2); set @y, 91; }
        else if(@s == 2) { set @map, 2935; set @x, rand(44,45); set @y, 83; }
        else { end; }

        break;
    }

    warp @sd, @map, @x, @y;

    message @sd, 3, "사냥터에 입장 되었습니다.";
    end;
}
Script    갈곳없는처녀귀신엔피씨    {
    set @id, myid();
    set @sd, mysd();
    callfunc("승급제한", 5);
    callfunc("소지품공간", 2);
A:
    switch($gguncngs)
    {
    case 0:
        set @pv, list2(@m,0,0,"흑흑.. 살아생전 한 많은 인생 살다 귀신이 된 귀신의 한을 들어봐 주시겠습니까?","진짜 불쌍해 보인다. 이야기라도 들어보자","귀신 주제에 무슨... 죽어랏!"); if(@pv == 0) { end; }
        if(@m == 0) { end; }
        else if(@m == 2)
        {
            say obj_getxy(5,5), 0, "갈곳없는처녀귀신: 감히 인간 주제에 망자를 해하려 하느냐!";
            sleep(1000);
            effect @id, 174;
            set_hp @sd, 0;
            set_mp @sd, 0;
            set_state @sd, 1;
            end;
        }

        set @pv, dialog(0,0,1,"어느 날, 어떤 돼지 같은 놈이 자신이 예맥흉가의 주인이랍시도 하인들을 이끌고 와서는 저희를 모두 쫓아냈답니다. 흑흑."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"우리는 1996년부터 예맥흉가에서 살았는데 이제와서 주인 행세라뇨! 정말 귀신이 곡할 노릇 아닌가요?"); if(@pv == 0) { end; }
        set @pv, list2(@s,0,0,"제발 그 돼지같은 놈을 찾아서 무찔러 주시겠어요?","네, 그렇게 해드리죠.","조금 더 생각 해볼게요..");
        if(@pv == 0) { end; } else if(@pv == -1) { goto A; } if(@s != 1) { end; }

        set $gguncngs, 1;
        goto A;
    case 1:
        if($m629 == 0)
        {
            set @pv, dialog(0,0,1,"예맥흉가는 이곳에서 나가셔서 오른쪽으로 쭉 걸어가시면 낡고 초라한 집이 보이는데, 그곳이 예맥흉가에요."); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"평소에 이 놈은 숨어있는데.. 먼저 <노>를 무찔러 <녹슨담뱃대>를 얻으시고, 그의 하수인인 <노비감시자>를 무찔러서"); if(@pv == 0) { end; }
            set @pv, dialog(0,0,1,"<주인의열쇠>를 얻으셔야 해요. <녹슨담뱃대>와 <주인의열쇠>를 가지고 계신다면, <주인의열쇠>를 사용해"); if(@pv == 0) { end; }
            set @pv, dialog(0,0,0,"그 돼지같은 놈이 있는곳으로 들어 가실 수 있을거에요. 그럼 부디 그놈을 내쫓아 주세요!");
            end;
        }

        set @pv, list2(@m,0,0,"그 돼지같은 흉가주인을 무찌르셨나요? 그를 무찔럿다면 저희들도 슬슬 자리를 예맥흉가로 다시 옮겨야겠어요.","네, 처치 했습니다.","조금만 더 기다려주세요.");
        if(@m != 1) { end; }

        set $m629, 0;
        set $gguncngs, 2;
        
        additem @sd, name2itemid("좋은짚신"), 1;
        set_birth @sd, get_birth(@sd) + 500;
        set_money @sd, get_money(@sd) + 25000;
        additem @sd, name2itemid("연합군패"), 6;

        set @pv, dialog(0,0,1,"정말 어떻게 감사를 표 해야할지.. 저희들이 예맥흉가로 왔을때부터 간직하고 있던 짚신을 하나 드릴게요."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"그렇게 좋은 짚신은 아니지만, 모험가 님에게 언젠가는 꼭 필요할 수 있으니 가져가 주세요."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"정말 감사합니다."); if(@pv == 0) { end; }

        message @sd, 8, "<b>[퀘스트 완료!]\n\n주화보상: 500원\n은전보상: 25,000전\n아이템보상1: 좋은짚신\n아이템보상2: 연합군패(6개)\n\n퀘스트 완료를 축하 합니다!";
        end;
    case 2:
        set @pv, dialog(0,0,0,"그 돼지같은 놈을 무찔러 줘서 정말 고마워요! 이제 우리들도 짐싸서 그곳으로 자리를 옮겨야겠어요.");
        end;
    }
}
Script    담배피는호랑이엔피씨    {
    set @id, myid();
    set @sd, mysd();
    callfunc("소지품공간", 1);

    set @m, list1("어서오세요. 어떻게 오셨나요?","낡은부적교환");
    switch(@m)
    {
    case 1:
        set @m, list1("어떤 부적을 가지고 오셨나?","봉인된안주인의영혼","봉인된주인의영혼");
        switch(@m)
        {
        case 1:
            set @m, list1("안주인의영혼이 담긴 부적을 가지고 왔나보군.. 이것으로는 보조 거울로 바꿔줄 수 있네. 바꾸겠나?","네, 바꿔 주세요.","조금 생각 해볼게요.");
            if(@m != 1) { end; }
            if(pc_amountitem(@sd, name2itemid("봉인된안주인의영혼")) < 1)
            {
A:
                set @pv, dialog(0,0,0,"이 부적이 없는것 같은데?");
                end;
            }
            delitem @sd, name2itemid("봉인된안주인의영혼"), 1;
            additem @sd, name2itemid("안주인의거울"), 1;

            set @pv, dialog(0,0,0,"자. 여기 거울을 가져가게나.");
            end;
        case 2:
            set @m, list1("주인의영혼이 담긴 부적을 가지고 왔나보군.. 이것으로는 방패로 바꿔줄 수 있네. 바꾸겠나?","네, 바꿔 주세요.","조금 생각 해볼게요.");
            if(@m != 1) { end; }
            if(pc_amountitem(@sd, name2itemid("봉인된주인의영혼")) < 1) { goto A; }
            delitem @sd, name2itemid("봉인된주인의영혼"), 1;
            additem @sd, name2itemid("예맥의연등"), 1;

            set @pv, dialog(0,0,0,"자. 여기 방패를 가져가게나.");
            end;
        }
    }
}
Script    담배피는호랑이말하기    {
    set @id, objid();
    set @r, rand(1,30);

    if(@r == 1) { say @id, 0, "담배피는호랑이: 예맥성에서 낡은 부적이나 물건을 구했다면, 가지고 와보게."; }
    else if(@r == 2) { say @id, 0, "담배피는호랑이: 자네 살면서 담배피는 호랑이 처음보았나? 나참~"; }
    else if(@r == 3) { say @id, 0, "담배피는호랑이: 이곳은 평화로운 예맥성이지. 헌데.. 요즘따라 이상한 것들이 출몰하더군?"; }
}
Script    장둔의영혼엔피씨    {
    set @id, myid();
    set @sd, mysd();
    set @mapid, get_mapid(@sd);

    if($m658 < 1 || $m659 < 1 || $m660 < 1)
    {
        set @pv, dialog(0,0,0,"이곳의 모든 내 부하들을 무찌르고 다시 나에게 말을 걸도록 하거라 하찮은 인간이여..");
        end;
    }

    if(magic_aethered(@sd, name2spellid("영혼영접")) != 0) { end; }

    set @pv, dialog(0,0,1,"너무 오랜만에 맡아보는 인간의 냄새구나.."); if(@pv == 0) { end; }
    set @pv, dialog(0,0,1,"이곳까지 나를 찾아오다니 정말 대단한 위용 이노라."); if(@pv == 0) { end; }
    set @pv, dialog(0,0,1,"너희들 인간이 이곳의 모든 나의 부하들을 무찔럿다면. 내 현신하여 네녀석들을 도력 해주도록 하지...!"); if(@pv == 0) { end; }

    magic_aether @sd, name2spellid("영혼영접"), 10;    
    
    for(set @i, 0; @i < get_mapwidth(@sd); set @i, @i + 1)
    {
        sleep(5);
        if(get_mapid(@sd) != @mapid) { end; }
        for(set @j, 0; @j < get_mapheight(@sd); set @j, @j + 1)
        {
            if(get_mapid(@sd) != @mapid) { end; }

            set @tg, obj_getxy(@i, @j);
            if(@tg == 0) { continue; }

            if(istype(@tg) == 2)
            {
                message @sd, 3, "문이 닫쳐 있습니다. 주위 몬스터들을 모두 처치하세요.";
                end;
            }
        }
    }

    set @target, obj_getxy(14,6);

    set $m658, 0;
    set $m659, 0;
    set $m660, 0;

    say @target, 1, "장둔의영혼: 나타나거라 내 위대한 현신이여!";
    mob_spawn 661, @mapid, rand(13,15), rand(7,8), 1;

    broadcast 0,4, "[예맥성외각] "+get_name(@sd)+"님이 장둔의 현신을 불러내었습니다! 처치후 환웅의 장구류를 얻어 보세요!!",0;
}
Script    외각보초엔피씨    {
    set @pv, dialog(0,0,1,"<b>잠깐 멈추시오!"); if(@pv == 0) { end; }
    set @pv, dialog(0,0,1,"이곳에는 장둔이라는 아주 무서운 몬스터가 숨어있는 곳이오."); if(@pv == 0) { end; }
    set @pv, dialog(0,0,0,"그의 수하들도 무시무시한 힘을 가지고 있으니, 가능한 일행과 함께 들어가길 바라오."); if(@pv == 0) { end; }
}
Script    선도환웅엔피씨    {
    set @id, myid();
    set @sd, mysd();
    callfunc("승급제한", 6);

    if($sdhw == 0)
    {
        set @m, list1("아이고.. 이거 어쩐다... 거기 자네 내 이야기를 들어 줄 수 있겠나?","네! 물론이죠.","아니요 갈 길이 바쁘네요..");
        if(@m != 1) { end; }

        set @pv, dialog(0,0,1,"정말 고맙네.. 어디 한 풀이를 할곳도 없고 저기 무뚝뚝한 보초한테 말은 걸기 싫고.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"참! 이야기가 딴데로 갔구만.. 요 근래 예맥성에 몬스터들이 많이 출몰하고 있다는건 알고 있지?"); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"근데 어느날 더러웃 옷차림의 사람처럼 생긴 몬스터가 집안 대대로 만든 환웅의 장비들을 모두 훔쳐갔지 뭔가.."); if(@pv == 0) { end; }
        set @pv, dialog(0,0,1,"아이고.. 조상들이 알면 경을 칠 일이야.."); if(@pv == 0) { end; }
        set @pv, dialog(1,0,1,"그 장비가 소중하긴 하지만.. 그런 악독한 몬스터놈에게 있을빠에야 자네같은 사람들이 가지고 있는것이 훨씬 낫네! 자네가 그놈을 무찔러서 만약 내 환웅장비를 얻는다면, 내 기꺼이 줌세!");
        set @pv, list2(@m,1,0,"우리 집안의 환웅장비는, 각성이 가능한 아주 신비로운 장비라네. 각성을 시킬 수 있는 재료들도 저놈들이 다 훔쳐갔으니.. 자네가 장비와 재료들을 가지고 온다면 기꺼이 각성 해주겠네. 나를 도와 주겠나?","네 기꺼이 참여 하겠습니다.","아뇨.. 너무 무섭네요.."); if(@pv == 0) { end; }
        if(@m != 1) { end; }

        set $sdhw, 1;
        set @pv, dialog(0,0,1,"정말 고맙네.. 장둔이라는 놈은 어디 동굴에 숨어있을것이니, 부디 몸 조심하게나.");
        end;
    }

    set @pv, list2(@s,1,0,"그래.. 장둔을 무찌르고 환웅의 장비를 구해왔나..? 헌데 내가 각성을 시켜 주고 싶어도 망치도 훔쳐가버려서 말이야.. 투구류와 반지류 그리고 무기류는 조합으로도 각성 할 수 있다네. 자네의 소지품에 있는 [ 라이브러리 ]에서 조합책★을 열어보게나.");
}