rAthena 베이스레벨업 보상 지급 NPC 및 무료 우편함

-    script    testMail    -1,{
OnPCBaseLvUpEvent:
    //Entire mail table struct
    //id, send_name, send_id, dest_name, dest_id, title, message, time, status, zeny, nameid, amount, refine, attribute, identify, card0, card1, card2, card3, unique_id, bound
    //메일 id, 보낸 캐릭터 명, 보낸 계정 id, 받는 캐릭터 명, 받는 계정 id, 제목, 내용, 시간, 상태, 첨부 제니, 첨부 아이템 id, 첨부 아이템 수량, 제련, 속성, 아이템 확인 여부, 카드0, 카드1, 카드2, 카드3, 아이템 고유 id, 아이템 구속 옵션
    
    //Mail struct
    //send_name, send_id, dest_name, dest_id, title, message, time, status
    //보낸 캐릭터 명, 보낸 계정 id, 받는 캐릭터 명, 받는 계정 id, 제목, 내용, 시간, 상태
    setarray .@reward_mail$[0], "'운영자'", "0", "'" + strcharinfo(0) + "'", getcharid(0), "'레벨 업 보상 아이템'", " ", gettimetick(2), "0";

    //메일 내용
    set .@reward_mail$[5], "'레벨 업을 축하드립니다. 아래는 보상 아이템입니다. -회신 불가'";
    
    //메일 하나 당 아이템 첨부 한 개 이므로 보상 레벨은 오름 차순으로 아래와 같이 작성해 주세요.
    
    //"보상 레벨",
    //"첨부 제니, 첨부 아이템 id, 첨부 아이템 수량, 제련, 속성, 아이템 확인 여부, 카드0, 카드1, 카드2, 카드3, 아이템 고유 id, 아이템 구속 옵션",
    //"보상 레벨",
    //"첨부 제니, 첨부 아이템 id, 첨부 아이템 수량, 제련, 속성, 아이템 확인 여부, 카드0, 카드1, 카드2, 카드3, 아이템 고유 id, 아이템 구속 옵션";
    setarray .@reward_item$[0],
        "10",
        "10000, 1202, 1, 20, 0, 1, 4006, 4006, 4006, 4006, 0, 0",
        "10",
        "10000, 19538, 1, 20, 0, 1, 0, 0, 0, 0, 0, 0",
        "20",
        "20000, 604, 5, 0, 0, 1, 0, 0, 0, 0, 0, 0",
        "20",
        "20000, 2455, 1, 20, 0, 1, 4454, 0, 0, 0, 0, 0",
        "80",
        "20000, 502, 20, 0, 0, 1, 0, 0, 0, 0, 0, 0",
        "80",
        "100000, 4454, 5, 0, 0, 1, 0, 0, 0, 0, 0, 0";

    .@i = 0;
    while(.@i < getarraysize(.@reward_item$))
    {
         if((BaseLevel < strtol(.@reward_item$[.@i], 10)) || (BaseLevel > strtol(.@reward_item$[getarraysize(.@reward_item$)-2], 10)))
            break;
        
        if(BaseLevel == strtol(.@reward_item$[.@i], 10))
        {
            set .@values$, implode(.@reward_mail$, ", ") + ", ";
            .@i += 1;
            .@values$ += .@reward_item$[.@i];
            query_sql("INSERT INTO `mail` (send_name, send_id, dest_name, dest_id, title, message, time, status, zeny, nameid, amount, refine, attribute, identify, card0, card1, card2, card3, unique_id, bound) VALUES (" + .@values$ + ")");
            message strcharinfo(0),"레벨업 보상이 우편함에 도착했습니다. 재접속 후에 수령 할 수 있으며 메일 사용에 이상이 있을 경우 재접속 후 우편함 또는 @mail 명령어를 이용하여  수령 할 수 있습니다.";
            dispbottom "우편함은 마을에 위치해 있습니다.";
            .@i += 1;
        } else {
            .@i += 2;
        }
    }

    end;
}

---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

-    script    우편함#dummy::mailBox    -1,{
//mail.txt npc가 rA에 포함되어 있지만 대화창과 제니를 요구하므로 무료로 바로 메일을 볼 수 있도록 했습니다.

    openmail;
    end;
}

// Morroc
//============================================================
morocc,164, 35,1    duplicate(mailBox)    우편함#moc1    888
morocc,170, 50,5    duplicate(mailBox)    우편함#moc2    888
// Payon
//============================================================
payon,196,105,3    duplicate(mailBox)    우편함#pay    888
//위와 같은 방식으로 원하는 위치 추가합니다.